GdPicture FORUMS

Is there a way to scan documents to multiple page PDF ?

- Sample for GdPicture V5: scanning-pdf-t15.html#p1761






- VB6 sample for GdPicture V4:

Code: Select all


'Here we will scan in a 24bpp  in multiple page pdf file
   Dim nImageCount As Long
   Dim nImageID As Long
   Dim nCpt As Long
   
   If oGdPicture.TwainOpenDefaultSource() Then
     
      nImageCount = 0

      oGdPicture.TwainSetAutoFeed (True)  'Set AutoFeed Enabled
      oGdPicture.TwainSetAutoScan (True) 'To  achieve the maximum scanning rate
     
      oGdPicture.TwainSetCurrentResolution (300)
      oGdPicture.TwainSetCurrentPixelType (TWPT_RGB) 'RGB
      oGdPicture.TwainSetCurrentBitDepth (8) ' 24 bpp
      oGdPicture.PdfNewPdf ("output.pdf")
     
      While oGdPicture.CreateImageFromTwain(Me.hWnd) <> 0
            nImageID = oGdPicture.GetNativeImage
            nImageCount = nImageCount + 1
            Call oGdPicture.PdfAddImageFromImageID(nImageID)
            oGdPicture.CloseImage (nImageID)
      Wend
     
      For nCpt = 1 To nImageCount
          Call oGdPicture.PdfSetPageDimensions(oGdPicture.PdfGetImageWidth(nCpt), oGdPicture.PdfGetImageHeight(nCpt))
          oGdPicture.PdfNewPage
          Call oGdPicture.PdfDrawImage(nCpt, 0, 0, oGdPicture.PdfGetImageWidth(nCpt), oGdPicture.PdfGetImageHeight(nCpt))
          oGdPicture.PdfEndPage
      Next nCpt
     
      oGdPicture.PdfSavePdf
      Call oGdPicture.TwainCloseSource
      MsgBox "Done !"
   Else
      MsgBox "can't open default source, twain state is: " & Trim(Str(oGdPicture.TwainGetState))
   End If




Note: This sample works with GdPicture Pro 3.7 Edition and superior.

HI!

Thanks for the code example. If my scanner is not an ADF scanner how would it be possible to scan docs to a multipage pdf thru VB/VBA code? My scanner uses a "next" button when the file format is set to pdf so that I am allowed to place another page into the scanner that will be appended to the PDF.

Thanks again,
Gil

I would like to use this demo code but I am having problems with the (Me.hWnd) references. It gives me a "Me not valid outside of class scope"

I may be missing something really stupid here but I am at a loss...

Thanks!

Hi,

You can use 0 if you are inside a class.


Regards,

Loïc

With GdPicture V5 it is a bit easier:

Code: Select all

Dim nImageID As Long
   
   If Imaging1.TwainOpenDefaultSource() Then
      Imaging1.TwainSetAutoFeed (True)  'Set AutoFeed Enabled
      Imaging1.TwainSetAutoScan (True) 'To  achieve the maximum scanning rate
     
      Imaging1.TwainSetCurrentResolution (300)
      Imaging1.TwainSetCurrentPixelType (TWPT_RGB) 'RGB
      Imaging1.TwainSetCurrentBitDepth (8) ' 24 bpp
      Imaging1.TwainPdfStart ("output.pdf")
     
      While Imaging1.CreateImageFromTwain(Me.hWnd) <> 0
            nImageID = Imaging1.GetNativeImage
            Call Imaging1.TwainAddGdPictureImageToPdf(nImageID)
            Imaging1.CloseImage (nImageID)
      Wend
     
      Imaging1.TwainPdfStop
      Call Imaging1.TwainCloseSource
      MsgBox "Done !"
   Else
      MsgBox "can't open default source, twain state is: " & Trim(Str(Imaging1.TwainGetState))
   End If